Подбор площади арматуры плиты по изгибающему моменту

 Рис.1 Эпюра перемещений по оси Z

 Рис.2 Эпюра изгибающих моментов Мx, т*м/м

 Рис.3 Эпюра армирования вдоль оси X, см2/м

 Рис.4 Эпюра изгибающих моментов Мн, т*м/м

Рис.5 Эпюра армирования вдоль оси Y, см2/м

Перемещения плиты

Текст программы

FINISH !

/CLEAR,START                             ! Старт системы заново

/UNDO,ON !

/CWD,'C:\!!! Ansys DOC\001 PLITA_ARM'    ! Задание рабочей папки

/FILNAME,PLITA_ARM                       ! Присвоение имени файлу базы данных

/TITLE,PLITA_ARM 

/COM,  Structural   

/UNITS,SI              ! Выбор системы измерения

/VUP,1,Z

/VIEW,1,1,2,3 !

/ANG,1                ! Выбор изометрии

/REP,FAST !

LX=9       ! Размер плиты вдоль оси X

LY=3       ! Размер плиты вдоль оси Y

Th=0.15     ! Толщина плиты в м

P1=-1       ! Распеределенная нагрузка в тс/м2

RS=36000    ! Прочность арматуры в тс/м2

MH=0.25     ! Размер сетки конечных элементов

/PREP7

ET,1,SHELL63        ! Выбор типа конечных элементов 

R,1,Th, , ,         ! Назначение толщины плиты   

MPTEMP,1,0          

MPDATA,EX,1,,3E6    ! Назначение модуля упрогости в т/м2

MPDATA,PRXY,1,,0.2  ! Назначение коэффициента пуассона

K,1,0,0,0           ! Задание ключевых точек

K,2,LX,0,0

K,3,LX,LY,0

K,4,0,LY,0

A,1,2,3,4           ! Постороение площади плиты

AESIZE,ALL,MH       ! Разбивка плиты на КЭ

AMESH,ALL

DL,2,,UX            ! Назначение граничных условий

DL,2,,UY

DL,2,,UZ

DL,4,,UX

DL,4,,UY

DL,4,,UZ

SFA,1,1,PRES,P1     ! Приложение нагрузки

FINISH  

/SOL                ! Вход в расчетный модуль

/STATUS,SOLU       

SOLVE   

FINISH  

/POST1              ! Вход в постпроцессор

/EFACET,1   

PLNSOL,U,Z,0,1                       ! Вывод на экран эпюр вертикальных перемещений по оси Z

ETABLE,MX,SMISC,4                    ! Формирование таблицы результатов изгибающих моментов MX

PLETAB,MX,AVG                        ! Вывод на экран эпюры изгибающих моментов MX

*get,n_elem,elem,,count              ! присваиваем переменной n_elem общее количество элементов

*DIM,ASX,ARRAY,n_elem,1,1, , ,       ! создаем пустой одномерный массив с количеством строк n_elem

ne=0 

*do,i,1,n_elem 

ne=elnext(ne)                            

*GET,mx1ei,ELEM,ne,ETAB,MX           ! вытаскиваем значение изгибающего момента (mx1ei) для данного элемента

asxei=(mx1ei*(-1)/(0.85*RS*Th))*10000     ! Вычисляем площадь арматуры в см2/м

ASX(i)=asxei                         ! заполняем пустой массив значениями площадей арматуры (номер строки равен номеру элемента) 

*enddo

ETABLE,ASX_etable,CENT,X                    

*VPUT,ASX,ELEM,,ETAB,ASX_etable,,,2

ETABLE,MY,SMISC,5

PLETAB,MY,AVG

*get,n_elem,elem,,count              ! присваиваем переменной n_elem общее количество элементов

*DIM,ASY,ARRAY,n_elem,1,1, , ,       ! создаем пустой одномерный массив с количеством строк n_elem

ne=0 

*do,i,1,n_elem 

ne=elnext(ne)                            

*GET,my1ei,ELEM,ne,ETAB,MY           ! вытаскиваем значение изгибающего момента (my1ei) для данного элемента

asyei=(my1ei*(-1)/(0.85*RS*Th))*10000     ! Вычисляем площадь арматуры в см2/м

ASY(i)=asyei                         ! заполняем пустой массив значениями площадей арматуры (номер строки равен номеру элемента) 

*enddo

ETABLE,ASY_etable,CENT,X                    

*VPUT,ASY,ELEM,,ETAB,ASY_etable,,,2