Исследование собственных колебаний металлической башни в программе Ansys

Рис.1 Расчетная схема башни

Рис.2 Результаты расчета частот собственных колебаний башни

Рис.3 Первая форма колебаний башни

Рис.4 Вторая форма колебаний башни

Рис.5 Третья форма колебаний башни

Рис.6 Четвертая форма колебаний башни

================== Программа модальный анализ башни =================

FINISH !
/CLEAR,START ! Старт системы заново
/UNDO,ON !

/CWD,'C:\!!! Ansys DOC\004 BASHNA_MOD' ! Задание рабочей папки
/FILNAME,BASHNA_MOD ! Присвоение имени файлу базы данных
/TITLE,MODALNY BASHNA

/UNITS,SI ! Выбор системы измерения

/VIEW,1,1,2,3 !
/ANG,1 ! Выбор изометрии
/REP,FAST !

A=2 ! Задание стороны треугольника, образующего мачту
H=2 ! Задание высоты секции мачты
N1=18 ! Задание количества секций
AR=3
FREQ_M=3.44

R1=0.219 ! Задание размеров трубы сечения стоек
T1=0.004 !
R2=0.08 ! Задание размера трубы сечения поясов
T2=0.004 !
R3=0.08 ! Задание размера трубы сечения раскосов
T3=0.004 !
R4=0.300
T4=0.004


/prep7

ET,1,180 ! Выбор типа конечных элементов
MP,EX,1,2E11 ! Задание характеристик материала модуль Юнга и коэфф Пуассона
MP,NUXY,1,0.3 !
UIMP,1,DENS,,,7800 ! Задание объемного веса материала
R,1,3.14*((R1+T1)**2-R1**2) ! Расчет площади сечения стойки мачты
R,2,3.14*((R2+T2)**2-R2**2) ! тоже пояса мачты
R,3,3.14*((R3+T3)**2-R3**2) ! тоже раскоса мачты
R,4,3.14*((R4+T4)**2-R4**2) ! тоже раскоса мачты

K,1,0,0,0 ! Задание точек треугольника мачты
K,2,0,0,a !
K,3,(a**2-(a/2)**2)**0.5,0,a/2 !

CSYS,4 ! Выбор локальной системы координат
WPROTA,,,-60 ! Разворот локальной системы координат на 60 град
K,,-AR ! Задание нижней точки опоры
WPROTA,,,60

WPOFFS,,,A ! Перенос локальной системы координат в другую точку
WPROTA,,,60
K,,-AR
WPROTA,,,-60

WPOFFS,,,-1
WPOFFS,(a**2-(a/2)**2)**0.5
K,,AR
! Выбор глобальной системы координат
CSYS,0

KSEL,S,,,1,3,1
KGEN,N1+1,all,,,,H ! Копирование точек треугольника N1 раз с шагом Н

ALLSEL,ALL

L,1,7 ! Создание линий стоек
L,2,8 !
L,3,9 !

L,1,9 ! Создание линий раскосов
L,3,8 !
L,2,7 !

L,7,9 ! Создание линий поясов
L,9,8 !
L,8,7 !

LGEN,N1,ALL,,,,H ! Копирование линий мачты на требуемую высоту

LSEL,S,LINE,,1,9*N1,9 ! Выбор линий стоек
LSEL,A,LINE,,2,9.2*N1,9 !
LSEL,A,LINE,,3,9.3*N1,9 !
LATT,1,1 ! Назначение номера материала и площади поперечного сечения

LSEL,S,LINE,,7,9*N1,9 ! Выбор линий поясов
LSEL,A,LINE,,8,9.2*N1,9 !
LSEL,A,LINE,,9,9.3*N1,9 !
LATT,1,2 ! Назначение номера материала и площади поперечного сечения

LSEL,S,LINE,,4,9*N1,9 ! Выбор раскосов
LSEL,A,LINE,,5,9.2*N1,9 !
LSEL,A,LINE,,6,9.3*N1,9 !
LATT,1,3 ! Назначение номера материала и площади поперечного сечения


L,4,13 ! Создание линий подпорок
L,5,14 !
L,6,15 !

LSEL,S,LINE,,9.04*N1,9.14*N1,1 ! Выбор линий подпорок
LATT,1,4 ! Выбор типа сечения


LSEL,ALL ! Выбор всех элементов схемы
LESIZE,ALL,,,1 ! Задание размера конечного элемента и разбивка
LMESH,ALL ! Создание КЭ

KSEL,S,,,1,6,1 ! Выбор нижних точек мачты

DK,ALL,UX,0 ! Закрепление нижних точек мачты
DK,ALL,UY,0 !
DK,ALL,UZ,0 !

ALLSEL,ALL ! Выбор всей схемы

NUMMRG,ALL ! Сшивка всей схемы

/SOLU ! Вход в решатель

ANTYPE,2 ! Выбор типа расчета: Модальный

EQSLV,SPAR !
MXPAND,10,,,1 !
LUMPM,0 !
PSTRES,0 !
MODOPT,LANB,10,1,1000,OFF !

SOLVE !

/POST1 !

SET,LIST

SET,FIRST ! Выбор результатов решения по первой форме колебаний
PLDISP,1 ! Графический вывод первой формы колебаний

================= Конец программы =========================

Определение НДС балки и оптимизация ее сечения средствами программы Ansys

Рис.1 Параметры расчетной схемы

Рис.2 Расчетная схема МКЭ

Рис.3 Эпюра поперечных сил, Н

Рис.4 Эпюра изгибающих моментов, Н*м

Рис.5 Эпюра максимальных напряжений в сечениях балки, Н/м2.
Максимальное напряжение возникающие в сечениях балки составляют 69 кг/мм2,
что превышает допустимое напряжение 14 кг/мм2 (сталь Ст3)

Рис.6 График зависимости размеров поперечного сечения балки от величины напряжений
при оптимизации по допускаемому напряжению

Рис.7 Результаты оптимизации сечения балки по итерациям

=============== ПРОГРАММА ОПРЕДЕЛЕНИЯ НДС И ОПТИМИЗАЦИИ БАЛКИ =======

/CWD,'C:\!!! Ansys DOC\003 BALKA_OPT' ! Задание рабочей папки
/FILNAME,BALKA_OPT ! Присвоение имени файлу базы данных
/TITLE,OPTIMIZATION OF BALKA ! Задание заголовка


/UNITS,SI ! Выбор системы измерения

! Задание параметров системы!

b=0.1 ! ширина сечения
h=0.2 ! высота сечения
l=6 ! длина балки
P=100000 ! величина равномерно-распределенной нагрузки


/PREP7 ! Вход в препроцессор

ET,1,BEAM3 ! Выбор типа конечных элементов - плоская балка
KEYOPT,1,9,0 ! Назначение опций типа конечных элементов
R,1,b*h,(b*h**3)/12,h ! Задание характеристик сечения

UIMP,1,EX,,,2e11 ! Назначение модуля Юнга материала
UIMP,1,NUXY,,,0.3 ! Назаначение коэффициента Пуассона материала


K,1,0,0,0 ! Ввод ключевых точек
K,2,l,0,0

L,1,2 ! Построение линии балки

LESIZE,ALL,,,20,,1,,,0 ! Задание параметров разбития на КЭ
LMESH,ALL ! Разбивка на КЭ

NSEL,S,NODE,,1,2,1 ! Выбор точек 1 и 2
D,ALL,,,,,,UX,UY,,,, ! Закрепление точек по X и Y

ESEL,S,ELEM,,1,20,1 ! Выбор всех КЭ балки
SFBEAM,ALL,1,PRES,P,,,,, ! Приложение равномернораспределенной нагрузки Р

ALLSEL,ALL ! Выбор все расчетной схемы

/SOLU ! Вход в расчетный модуль

SOLVE ! Команда на расчет

/POST1 ! Вход в постпроцессор

ETABLE,MFORY_I,SMISC,2 ! Формирование таблицы поперечных сил в балке в i-ой точке КЭ
ETABLE,MFORY_J,SMISC,8 ! Формирование таблицы поперечных сил в балке в j-ой точке КЭ
PLLS,MFORY_I,MFORY_J ! Построение эпюры поперечных сил в балке

ETABLE,MMOMZ_I,SMISC,6 ! Формирование таблицы изгибающих моментов в балке в i-ой точке КЭ
ETABLE,MMOMZ_J,SMISC,12 ! Формирование таблицы изгибающих моментов в балке в j-ой точке КЭ
PLLS,MMOMZ_I,MMOMZ_J ! Построение эпюры изгибающих моментов в балке


ETABLE,EVOLUME,VOLU ! Формирование таблицы объемов отдельных КЭ
SSUM ! Суммирование объема отдельных КЭ балки и вывод значения на экран
*GET,VOLUME,SSUM,,ITEM,EVOLUME ! Задание объема балки как параметра

ETABLE,SMAX_I,NMISC,1 ! Формирование таблицы максимальных напряжений в сечении балки в i-ой точке КЭ
ESORT,ETAB,SMAX_I,0,1,, ! Сортировка таблицы в порядке по убыванию для нахождения максимального значения
*GET,SMAXI,SORT,,MAX ! Задание максимального напряжения в i-ой точке КЭ как параметра

ETABLE,SMAX_J,NMISC,3 ! Формирование таблицы максимальных напряжений в сечении балки в j-ой точке КЭ
ESORT,ETAB,SMAX_J,0,1,, ! Сортировка таблицы в порядке по убыванию для нахождения максимального значения
*GET,SMAXJ,SORT,,MAX ! Задание максимального напряжения в j-ой точке КЭ как параметра

PLLS,SMAX_I,SMAX_J ! Построение эпюры максимальных напряжений в сечении элемента

SMAX=SMAXI>SMAXJ ! Присвоение максимального значения из SMAX_I и SMAX_J переменной SMAX

LGWRITE,'1','LGW','C:\!!! Ansys DOC\003 BALKA_OPT',COMMENT ! Сохранение файла

/OPT ! Вход в модуль оптимизации

OPANL,'1','LGW','C:\!!! Ansys DOC\003 BALKA_OPT' ! Открытие файла задачи для оптимизации


! Задание параметров оптимизации !

! Задание переменных конструкции DV's!
OPVAR,B,DV,0.1,0.4,0.1 ! Задание границ изменения ширины балки и задание допуска
OPVAR,H,DV,0.2,0.8,0.1 ! Задание границ изменения высоты балки и задание допуска

! Задание переменных состояния SV's!
OPVAR,SMAX,SV,1.37E8,1.4E8,1E3 ! Задание изменения границ максимальных напряжений в сечениях балки и задание допуска

! Задание целевой функции OV!
OPVAR,VOLUME,OBJ,,,1E-3 ! Задание допуска изменения объема


OPTYPE,FIRS ! Выбор метода решения задачи оптимизации
OPFRS,30,100,0.2 ! Выбор параметров решения задачи оптимизации, кол-во итераций и их характеристики

OPEXE ! Команда на оптимизацию конструкции


XVAROPT,SMAX ! Построение графика результатов оптимизации по Х откладываем максимальное значение напряжений
PLVAROPT,B,H ! По Y откладываем высоту и ширину сечения балки


/POST1 ! Вход в постпроцессор

PLLS,SMAX_I,SMAX_J ! Построение эпюры максимальных напряжений в сечении элемента
! после оптимизации


=============== КОНЕЦ ПРОГРАММЫ ==============

Исследование работы металлической балки в Ansys

Рис.1 Параметры балки

Рис.2 Расчетная модель балки МКЭ

Рис.3 Деформации балки

Рис.4 Векторы главных напряжений

Рис.5 Эпюры поперечных напряжений, Па

Рис. 6 Эпюры продольных напряжений, Па

Рис.7 Векторы перемещений

Рис.8 Продольные напряжения в середине пролета балки, Па

===========ПРОГРАММА РАСЧЕТА БАЛКИ=========


/CWD,'C:\!!! Ansys DOC\002 BALKA' ! Задание рабочей папки

/NOPR !
/PMETH,OFF,0 ! Задание вида расчета
KEYW,PR_SET,1 !
KEYW,PR_STRUC,1 !
KEYW,PR_THERM,0 !
KEYW,PR_FLUID,0 !
KEYW,PR_ELMAG,0 !
KEYW,MAGNOD,0 !
KEYW,MAGEDG,0 !
KEYW,MAGHFE,0 !
KEYW,MAGELC,0 !
KEYW,PR_MULTI,0 !
KEYW,PR_CFD,0 !
/GO !

/COM, !
/COM,Preferences for GUI filtering have been set to display: !
/COM, Structural !



/UNITS,SI ! Выбор системы измерения
/FILNAME,BALKA ! Присвоение имени файлу базы данных
/TITLE,BALKA ! Задание заголовка


/prep7 ! Вход в предпроцессор

ET,1,92,,,,,1 ! Выбор типа конечных элементов
MP,EX,1,2E11 ! Задание характеристик материала модуль Юнга и коэфф Пуассона
MP,NUXY,1,0.24 !

k,1,0,0,0 !
k,2,0,0.010,0 !
k,3,0.095,0.010,0 !
k,4,0.095,0.390,0 ! Задание точек поперечного сечения
k,5,0,0.390,0 !
k,6,0,0.400,0 !
k,7,0.200,0.400,0 !
k,8,0.200,0.390,0 !
k,9,0.105,0.390,0 !
k,10,0.105,0.010,0 !
k,11,0.200,0.010,0 !
k,12,0.200,0,0 !

A,1,2,3,4,5,6,7,8,9,10,11,12 ! Построение поверхности поперечного сечения

VOFFST,1,6,, ! Выдавливание поверхности в объемное тело

/VIEW,1,1,1,1 ! Переход вида к изометрии
/ANG,1 !
/REP,FAST !

DL,12,,ALL ! Задание закрепления
DL,24,,ALL ! Задание закрепления

SFA,8,1,PRES,500000 ! Приложение нагрузки к верхнему поясу балки

ESIZE,0.1 ! Задание размера конечных элементов

VMESH,ALL ! Разбивка балки на конечные элементы

FINISH ! Выход из предпроцессора


/SOLU ! Вход в решатель
SOLVE ! Команда на расчет
FINISH ! Остановка решателя

============== КОНЕЦ ПРОГРАММЫ==============

Расчет фермы в Ansys

Рис.1 Расчетная схема фермы с номерами элементов

Рис.2 Характер деформации фермы

Рис.3 Эпюры нормальных усилий в элементах фермы

========== ПРОГРАММА РАСЧЕТА ФЕРМЫ===============

/CWD,'C:\!!! Ansys DOC\001 FERMA' ! Задание рабочей папки

/NOPR !
/PMETH,OFF,0 ! Задание вида расчета
KEYW,PR_SET,1 !
KEYW,PR_STRUC,1 !
KEYW,PR_THERM,0 !
KEYW,PR_FLUID,0 !
KEYW,PR_ELMAG,0 !
KEYW,MAGNOD,0 !
KEYW,MAGEDG,0 !
KEYW,MAGHFE,0 !
KEYW,MAGELC,0 !
KEYW,PR_MULTI,0 !
KEYW,PR_CFD,0 !
/GO !

/COM, !
/COM,Preferences for GUI filtering have been set to display: !
/COM, Structural !



/UNITS,SI ! Выбор системы измерения
/FILNAME,FERMA ! Присвоение имени файлу базы данных
/TITLE,FERMA ! Задание заголовка

B1=1
P=10

/prep7 ! Вход в предпроцессор

/ANTYPE,0 ! Определение типа анализа - Статический

k,1,0,0,0 !
k,2,1,0,0 !
k,3,2,0,0 !
k,4,3,0,0 ! Задание точек фермы
k,5,4,0,0 !
k,6,1,1,0 !
k,7,2,1,0 !
k,8,3,1,0 !

LSTR,1,6 !
LSTR,6,2 !
LSTR,6,7 !
LSTR,6,3 !
LSTR,8,3 ! Задание линий фермы
LSTR,8,4 !
LSTR,8,5 !
LSTR,7,8 !
LSTR,1,2 !
LSTR,2,3 !
LSTR,3,4 !
LSTR,4,5 !
LSTR,7,3 !

ET,1,1 ! Выбор типа конечных элементов
MP,EX,1,2E11 ! Задание характеристик материала модуль Юнга и коэфф Пуассона
MP,NUXY,1,0.3 !
R,AREA,B1*B1 ! Задание площади сечения элементов

LSEL,ALL
LESIZE,ALL,,,1 ! Задание размера конечного элемента и разбивка
LMESH,ALL

DK,1,UX,0 ! Задание закреплений
DK,1,UY,0 !
DK,5,UX,0 !
DK,5,UY,0 !
FK,6,FY,-P ! Задание действующих сил
FK,7,FY,-P !
FK,8,FY,-P !

FINISH ! Выход из предпроцессора

/SOLU ! Вход в решатель
SOLVE ! Команда на расчет
FINISH ! Остановка решателя


/POST1 ! Вход в постпроцессор

/PNUM,ELEM,1 ! Нумерация элементов

/SHOW,JPEG,,0 ! Сохранение снимка экрана с нумерацией элементов
JPEG,QUAL,100, ! необходимо для чтения таблицы по услиям
JPEG,ORIENT,HORIZ !
JPEG,COLOR,2 !
JPEG,TMOD,1 !
/GFILE,800, !
/REPLOT !
/SHOW,CLOSE !
/DEVICE,VECTOR,0 !

/PNUM,ELEM,0 ! Отмена нумерации элементов

SET,1 ! Чтение результатов первого шага
PLDISP,1 ! Вывод на экран деформированной схемы

/SHOW,JPEG,,0 ! Сохранение снимка экрана деформированной схемы
JPEG,QUAL,100, !
JPEG,ORIENT,HORIZ !
JPEG,COLOR,2 !
JPEG,TMOD,1 !
/GFILE,800, !
/REPLOT !
/SHOW,CLOSE !
/DEVICE,VECTOR,0 !


ETABLE,FI,SMISC,1 ! Формирование таблицы результатов для построения эпюр
ETABLE,FJ,SMISC,1 !
PLLS,FI,FJ ! Вывод на экран эпюр

/SHOW,JPEG,,0 ! Сохранение снимка экрана с эпюрами
JPEG,QUAL,100, !
JPEG,ORIENT,HORIZ !
JPEG,COLOR,2 !
JPEG,TMOD,1 !
/GFILE,800, !
/REPLOT !
/SHOW,CLOSE !
/DEVICE,VECTOR,0 !

PRETAB,FI,FJ ! Вывод на экран таблицы с усилиями в элементах

============КОНЕЦ=================

Расчет плавательного бассейна с техническим этажем под днищем

Рис.1 Вид КЭ модели бассейна (сечение)

Рис.2 Вид векторов деформаций в плоскости ZOX

Рис.3 Вид векторов деформаций в плоскости ZOY

Рис.4 Изополя перемещений по оси Z

Рис.5 Изополя перемещений по оси Z в плитной части на грунте

Рис.6 Изполя отпора грунта Rz

Рис.7 Изополя напряжений Nx

Рис.8 Изполя изгибающего момента Mx

Расчет железобетонной чаши индивидуального бассейна на упругом основании

Рис.1 Общий вид КЭ модели чаши бассейна

Рис. 2 Вид деформаций чаши бассейна в плоскости ZOX

Рис. 3 Вид деформаций чаши бассейна в плоскости ZOY

Рис.4 Изополя деформаций по оси Z днища бассейна

Рис.5 Изополя момента Мх в днище и стенка чаши бассейна

Рис.6 Изополя нормальных напряжений Nx в днище и стенках чаши бассейна

Блок-модульная котельная

Устройство свай

Свайный фундамент под опору для дымовых труб

Расчет анкерных болтов

Расчет буронабивных свай

Высотная и плановая съемка путей трансбордера

Рампа погрузочно-разгрузочная. Конструкции железобетонные